19 Fourierreihen

Mathematische Grundlagen für das Lehramtsstudium Physik

Franz Embacher, Universität Wien, 2008
http://homepage.univie.ac.at/franz.embacher/grundlagen/

Berechnung und Darstellung einer Fourierreihe

Die zu entwickelnde Funktion

Sie muss nur im Intervall [-π,π] angegeben werden!

f[x_]:=(x^3);

Die periodisch fortgesetzte Funktion

Der folgende Schritt ist nur notwendig, wenn Sie die Funktion über mehrere Perioden plotten wollen.

fPeriodisch[x_]:=If[-π<x≤π,f[x],If[x≤-π,f[x+2π],If[x>π,f[x-2π]]]]
Plot[fPeriodisch[x],{x,-3π,3π},Ticks->{{-3π,-2π,-π,π,2π,3π},Automatic},PlotStyle->Red]

Die senkrechten Striche, die Mathematica hier zeichnet, sind nicht Teil des Graphen - ignorieren Sie sie einfach!

Die Fourierkoeffizienten

a[0]=(1/π)Integrate[f[x],{x,-π,π}]
a[n_]=(1/π)Integrate[Cos[n x]f[x],{x,-π,π},Assumptions->n∈Integers]
b[n_]=(1/π)Integrate[Sin[n x]f[x],{x,-π,π},Assumptions->n∈Integers]

Bemerkung zum Code: Mit der Option Assumptions->n∈Integers (das Zeichen ∈ schreiben Sie durch Eingabe der Zeichen \ und danach [Element], oder Sie ersetzen "n∈Integers" durch "Element [n,Integers]" ) teilen Sie Mathematica mit, dass n ganzzahlig sein soll und ersparen sich damit, im Nachhinein Identitäten wie sin(n x)=0 und cos(n x)=(((-1))^n) zu verwenden!

Plot der Summe der ersten 16 Reihenglieder

Plot[((a[0])/2)+Sum[a[n]Cos[n x]+b[n]Sin[n x],{n,1,15}],{x,-3π,3π},PlotRange->All,PlotStyle->Red,Ticks->{{-3Pi,-2Pi,-Pi,Pi,2Pi,3Pi},Automatic}]

Stückweise definierte Funktionen

Stückweise definierte Funktionen können Sie beispielsweise in der Form

χ[x_]:=If[0≤x<π,x^2,-x];

eingeben. Können Sie den Code entziffern? Wie sieht der Graph dieser Funktion im Intervall [-π,π] aus? Denken Sie zuerst nach, bevor Sie sich ihn ansehen!

Plot[χ[x],{x,-π,π},Ticks->{{-Pi,Pi},Automatic},PlotStyle->Red] (* Führen Sie zuerst die obige Definition von χ aus! *)

Mathematica kann auch solche Funktionen geschlossen integrieren! Beispiel:

(1/π)Integrate[Cos[n x]χ[x],{x,-π,π},Assumptions->n∈Integers]

Zu Aufgabe 14

Spielen Sie diese Darstellung als Animation ab!

Manipulate[Plot[1+Cos[x]Exp[-t],{x,-Pi,Pi},PlotRange->{0,2}],{t,0,10,0.1}]