18 Elemente der Wahrscheinlichkeitsrechnung

Mathematische Grundlagen für das Lehramtsstudium Physik

Franz Embacher, Universität Wien, 2008
http://homepage.univie.ac.at/franz.embacher/grundlagen/

Wahrscheinlichkeitsverteilungen

Binomialverteilung

n=21;
q=(1/3);
ListPlot[Table[{k ,Binomial[n,k](q^k)(((1-q))^((n-k)))},{k,0,n}],PlotStyle ->{PointSize[0.014],  Red}, AxesLabel->{"k","p(k)"},AxesOrigin->{0,0},PlotRange->{{-0.5,26.5},{-0.005,0.215}}]

Mathematica kann nicht nur numerrische  Summen berechnen, sondern auch symbolische, hier am Beispiel der Normierung, der Erwartungswerte von k und (k^2) sowie der Standardabweichung der allgemeinen Binomialverteilung:

Clear[n,q]; (* Vorherige Definition von n und q wird gelöscht *)
Sum[Binomial[n,k](q^k)(((1-q))^((n-k))),{k,0,n}]//Simplify//PowerExpand (* Normierung *)
Sum[k Binomial[n,k](q^k)(((1-q))^((n-k))),{k,0,n}]//Simplify//PowerExpand (* <k> = Erwartungswert *)
Sum[(k^2) Binomial[n,k](q^k)(((1-q))^((n-k))),{k,0,n}]//Simplify//PowerExpand (* <(k^2)> *)
Sqrt[%-%%^2] //Simplify (* Standardabweichung *)

Poissonverteilung

μ=7;
ListPlot[Table[{k ,((μ^k)/(k!)) Exp[-μ]},{k,0,26}],PlotStyle ->{PointSize[0.014], Red}, AxesLabel->{"k","p(k)"},AxesOrigin->{0,0},PlotRange->{{-0.5,26.5},{-0.005,0.215}}]

Statistische Kennzahlen der allgemeinen Poissoinverteilung (Beachten SIe, das Mathemtica hier Reihen berechnet):

Clear[μ]; (* Vorherige Definition von μ wird gelöscht *)
Sum[((μ^k)/(k!)) Exp[-μ],{k,0,∞}] (* Normierung *)
Sum[k ((μ^k)/(k!)) Exp[-μ],{k,0,∞}] (* <k> = Erwartungswert *)
Sum[(k^2) ((μ^k)/(k!)) Exp[-μ],{k,0,∞}] (* <(k^2)> *)
Sqrt[%-%%^2] (* Standardabweichung *)

Exponentialverteilung

κ=1;
Plot[κ Exp[-κ x],{x,0,5},PlotRange->{-0.02,1.055},PlotStyle ->Red,AxesLabel->{"t","r(t)"}]

Statistische Kennzahlen der Exponentialverteilung:

Clear[κ]; (* Vorherige Definition von κ wird gelöscht *)
Integrate[κ Exp[-κ x],{x,0,∞},Assumptions->κ>0] (* Normierung *)
Integrate[x κ Exp[-κ x],{x,0,∞},Assumptions->κ>0] (* <x> = Erwartungswert *)
Integrate[(x^2) κ Exp[-κ x],{x,0,∞},Assumptions->κ>0] (* <(x^2)> *)
Sqrt[%-%%^2] //PowerExpand (* Standardabweichung *)

Bemerkung zum Code: Mit der Option Assumptions des Integrate-Befehls ersparen Sie es Mathematica, beim Integrieren Spezialfälle, die Sie gar nicht interessieren, zu berücksichtigen.

Normalverteilung

μ=7;
σ=2.16;
Plot[(1/(σ(Sqrt[2π])))Exp[-((((x-μ))^2)/(2(σ^2)))],{x,-3,25},PlotRange->{0,0.205},PlotStyle ->Red,AxesLabel->{"x","r(x)"}]

Statistische Kennzahlen der Normalverteilung:

Clear[μ,σ]; (* Vorherige Definition von μ und σ wird gelöscht *)
Integrate[(1/(σ(Sqrt[2π])))Exp[-((((x-μ))^2)/(2(σ^2)))],{x,-∞,∞},Assumptions->σ>0] (* Normierung *)
Integrate[x (1/(σ(Sqrt[2π])))Exp[-((((x-μ))^2)/(2(σ^2)))],{x,-∞,∞},Assumptions->σ>0] (* <x> = Erwartungswert *)
Integrate[(x^2) (1/(σ(Sqrt[2π])))Exp[-((((x-μ))^2)/(2(σ^2)))],{x,-∞,∞},Assumptions->σ>0] (* <(x^2)> *)
Sqrt[%-%%^2] //PowerExpand (* Standardabweichung *)

Normalverteilung, interaktiv

Mittelwert μ und Standardabweichung σ können mit Hilfe der Schieberegler gewählt werden.

Manipulate[
Plot[(1/(σ(Sqrt[2π])))Exp[-((((x-μ))^2)/(2(σ^2)))],{x,-10,10},PlotRange->{0,1.5},PlotStyle ->Red,AxesLabel->{"x","r(x)"},ImageSize->500],
{{μ,1},-2,3,Appearance->"Labeled"},{{σ,1},0.3,2,Appearance->"Labeled"}]

Zufallszahlen

Reelle Zufallszahl zwischen 0 und 1 (gleichverteilt)

Random[]

Liste solcher Zufallszahlen

Table[Random[],{100}]

Reelle Zufallszahlen zwischen 2 und 5 (gleichverteilt)

Table[Random[Real,{2,5}],{30}]

DIskrete Zufallszahlen (0 oder 1)

Table[Random[Integer],{30}]

Diskrete Zufallszahlen (Würfeln: 1 bis 6)

Table[Random[Integer,{1,6}],{30}]

Zu Aufgabe 23

Interpretieren Sie, was Sie hier sehen!

Table[Sum[Random[],{20}],{10000}];
ListPlot[%]