17 Lineare Algebra: Eigenwerte und Eigenvektoren

Mathematische Grundlagen für das Lehramtsstudium Physik

Franz Embacher, Universität Wien, 2008
http://homepage.univie.ac.at/franz.embacher/grundlagen/

Eigenwerte und EIgenvektoren berechnen

Eigenwerte berechnen

A={{-3,1,0},{0,4,7},{0,0,4}};
MatrixForm[A]
Eigenvalues[A]

Die Eigenwerte sind 4 (zweifach) und -3 (einfach).

Eigenvektoren berechnen

A={{-3,1,0},{0,4,7},{0,0,4}};
MatrixForm[A]
Eigenvectors[A]

Eigenvektoren sind:
       zum Eigenwert 4 ............  (({{1}, {7
0}})) 
       zum Eigenwert -3 .........  (({{1}, {0
0}}))
Anmerkung: Der Nullvektor  (({{0}, {0
0}})) kann ignoriert werden. Durch seine Anzeige drückt Mathematica aus, dass es neben dem zuvor ausgegebenen EIgenvektor zum EIgenwert 4 keinen zweiten, davon linear unabhängigen EIgenvektor zum selben Eigenwert gibt.

EIgenwerte und EIgenvektoren zugleich berechnen

A={{-3,1,0},{0,4,7},{0,0,4}};
MatrixForm[A]
Eigensystem[A]

Mathematica gibt eine Liste aus, die aus zwei Listen besteht: Di erste gibt die EIgenwerte an, wie sie auch mit Eigenvalues ermittelt werden können, die zweite gibt jene Eigenvektoren an, die auch die Operation Eigenvectors ausgibt.

Interaktive Visualisierung der Wirkung einer reellen 2×2-Matrix

Version 1

Hier ist für eine einzugebende reelle 2×2-Matrix gezeigt, in welche Punktmenge der Einheitskreis übergeführt wird. Sehen SIe sich den Code an! Verstehen Sie ihn? Erinnern Sie sich an die Parameterdarstellung einer Kurve (Kapitel 12)!

Manipulate[
ParametricPlot[{a11 Cos[t] + a12 Sin[t],a21 Cos[t] + a22 Sin[t]},{t,0,2π},PlotRange->{{-3,3},{-3,3}},PlotStyle->Red],
{{a11,1.5,"(Subscript[a, 11])"},-3,3,Appearance->"Labeled"},
{{a12,0.3,"(Subscript[a, 12])"},-3,3,Appearance->"Labeled"},
{{a21,0.3,"(Subscript[a, 21])"},-3,3,Appearance->"Labeled"},
{{a22,2,"(Subscript[a, 22])"},-3,3,Appearance->"Labeled"},
ControlPlacement->Right]

Version 2

Hier eine ausgefeiltere Version: Es ist zusätzlich der EInheitskreis dargestellt, und 24 Punkte am EInheitskreis sind mit ihren Bildpunkten durch Pfeile verbunden. Aufgabe: Überlegen Sie, wie Sie anhand dieser Visualisierung die (reellen) Eigenräume und EIgenwerte der jeweisl eingestellten Matrix (näherungsweise) ablesen können!

Manipulate[
Show[
ParametricPlot[{a11 Cos[t] + a12 Sin[t],a21 Cos[t] + a22 Sin[t]},{t,0,2π},PlotStyle->Red,PlotRange->{{-3,3},{-3,3}}],ParametricPlot[{Cos[t],Sin[t]},{t,0,2π},PlotStyle->Dashed],
Graphics[
Table[Arrow[{{Cos[t],Sin[t]},{a11 Cos[t]+a12 Sin[t],a21 Cos[t]+a22 Sin[t]}}],{t,0,2π,π/12}]]
]
,
{{a11,1.5,"(Subscript[a, 11])"},-3,3,Appearance->"Labeled"},
{{a12,0.3,"(Subscript[a, 12])"},-3,3,Appearance->"Labeled"},
{{a21,0.3,"(Subscript[a, 21])"},-3,3,Appearance->"Labeled"},
{{a22,2,"(Subscript[a, 22])"},-3,3,Appearance->"Labeled"},
ControlPlacement->Right]

"e hoch einer Matrix"

MatrixExp[t {{-k,-1},{1,-k}}]
MatrixForm[%]

Diagonalisierung und Spektraldarstellung einer Matrix

Diagonalisierung

Für diagonalisierbare Matrix A existiert eine invertierbare Matrix S, so dass (S^(-1))A S eine Diagonalmatrix (mit den Eigenwerten von A auf der Hauptdiagonale) ist. Die Matrizen A und (S^(-1))A S heißen zueinander ähnlich. Die Matrix S, die A diagonalisiert, lässt sich mit Mathematica leicht ermitteln:

(A={{2,3},{4,5}})//MatrixForm (* gegebene Matrix - sie kann auch höherdimensional sein *)
(S=Transpose[Eigenvectors[A]]//Simplify)//MatrixForm
Det[S] (* Falls det(S) ≠ 0 ist, ist A diagonalisierbar. In diesem Fall ist S die Matrix, die A diagonalisiert. Sie enthält die EIgenvektoren von A als Spalten. *)
Inverse[S].A.S//Simplify//MatrixForm (* die zu A ähnliche Diagonalmatrix *)

Spektraldarstellung

Mit Hilfe der Matrix S können die in der Spektraldarstellung vorkommenden Projektionen auf die Eigenräume berechnet werden. Anhand des obigen Beispiels:

(P1=S.{{1,0},{0,0}}.Inverse[S]//Simplify)//MatrixForm
(P2=S.{{0,0},{0,1}}.Inverse[S]//Simplify)//MatrixForm
(* Check: *)
P1+P2//Simplify//MatrixForm (* ergibt die EInheitsmatrix *)
P1.P2//Simplify//MatrixForm (* ergibt 0 *)
P2.P1//Simplify//MatrixForm (* ergibt 0 *)
Eigenvalues[A][[1]] P1+Eigenvalues[A][[2]] P2//Simplify//MatrixForm  (* ergibt A ... das ist die Spektraldarstellung von A! *)