16 Lineare Algebra: Matrizen, lineare 
Gleichungssysteme und lineare Operatoren

Mathematische Grundlagen für das Lehramtsstudium Physik

Franz Embacher, Universität Wien, 2008
http://homepage.univie.ac.at/franz.embacher/grundlagen/

Eingabe und Ausgabe von Matrizen

Definition einer Matrix

Eine Matrix wird als Liste von Listen eingegeben:

A={{1,2},{3,4}} (* 2×2-Matrix *)
u={{2},{4}} (* Spaltenvektor = 2×1-Matrix *)
v={{2,4}} (* Zeilenvektor = 1×2-Matrix *)

Eingabe mit Hilfe der Palette

Mit Hilfe der Palette BasicMathInput können Sie 2×2-Matrizen in der üblichen Matrizenschreibweise eingeben:

A=(({{1, 2}, {3, 4}}))

Das Ergebnis ist dasselbe wie bei der Eingabe der Matrix als Liste von Listen.

Ausgabe in Matrixform

MatrixForm[A]
MatrixForm[u]
MatrixForm[v]

Beachten Sie, dass Sie mit einem Objekt der Form MatrixForm[A] nicht rechnen können! Es dient nur der Anzeige. Durch den Befehl

MatrixForm[B={{5,6},{6,8}}]

können Sie eine Matrix definieren und zugleich in herkömmlicher  Form anzeigen lassen. Danach ist die Matrix B definiert:

B

Einheitmatrix

IdentityMatrix[4] (* 4×4-Einheitsmatrix  *)
%//MatrixForm

Diagonalmatrix

DiagonalMatrix[{5,2,3}]
%//MatrixForm

Matrix mit unbestimmten Koeffizienten

Die Verwendung von "allgemeinen" Matrizen ist beispielsweise dann sinnvoll, wenn Sie Beziehungen, die für alle Matrizen gelten, beweisen wollen!

Array[a,{2,3}]
%//MatrixForm

Matrizen durch ein Bildungsgesetz definieren

Table[j+k,{j,1,3},{k,1,3}]
%//MatrixForm

Matrizenmultiplikation

Matrizenmultiplikation

Die Matrizenmultiplikation wird mit einem Punkt . geschrieben!

A={{1,2},{3,4}}
B={{5,6},{6,8}}
A.B

Sie können die gleiche Rechnung auch ausführen:

MatrixForm[A={{1,2},{3,4}}]
MatrixForm[B={{5,6},{6,8}}]
MatrixForm[A.B]

Achtung:

Wird der Punkt . weggelassen, so erhalten Sie das kompnentenweise Produkt der Matrizen!

MatrixForm[A .B] (* Produkt der Matrizen A und B *)
MatrixForm[A B] (* Achtung: Das ist nicht das Produkt der Matrizen A und B! *)

Weitere Operationen für Matrizen

Die folgenden Operationen werden auf die Matrix

A=(({{3, -4}, {2+I, 7I}}))

angewandt. Ändern SIe die folgenden Zellen, um die Resultate mit MatrixForm in herkömmlicher Darstellung anzuzeigen!

Inverse einer Matrix

Inverse[A]

Spur einer Matrix

Tr[A]

Determinante einer Matrix

Det[A]

Transponierte einer Matrix

Transpose[A]

Adjungierte einer Matrix

Transpose[Conjugate[A]]

Anzahl der Zeilen und Spalten einer Matrix

B={{-1,7,5},{4,9,0}};
Dimensions[B]

Potenz einer Matrix

MatrixPower[A,4] (* ist dasselbe wie A.A.A.A *)

Rang einer Matrix

MatrixRank[A]

Lineare Gleichungssysteme

Lösen mittels Solve

Solve[{3x+2y-5z==4,2x+6y+9z==5,4x-y-5z==3},{x,y,z}]

Solve[{3x+2y-5z==4,2x+6y+9z==5,3x+2y-5z-4==0},{x,y,z}]

Solve[{3x+2y-5z==4,2x+6y+9z==5,3x+2y-5z==7},{x,y,z}]

Sie können ein lineares Gleichungssystem auch durch eine Matrix definieren und es mit Solve lösen:

A=(({{1, 2}, {3, 4}}));
Solve[A.{{x},{y}}=={{5},{6}},{x,y}]

xVektor={{x},{y}};
bVektor={{5},{6}};
Solve[A.xVektor==bVektor,{x,y}]

Lösen mittels Reduce

Beachten Sie, dass die von Mathematica für das folgende Gleichungssystem angegebene Lösung für den Fall b=2/3 falsch ist:

Solve[{x+2b y==5,3x+4y==6},{x,y}]

Die Funktion Reduce kann wie Solve verwendet werden. Sie berücksichtigt alle Eventualitäten:

Reduce[{x+2b y==5,3x+4y==6},{x,y}]

Reduce[{x+2b y==7/3,3x+4y==7},{x,y}]

Interaktive Visualisierung: lineare 2×2-Gleichungssysteme

Jede der gezeigten Geraden ist Lösungsmenge einer Gleichung des (rellen) linearen Gleichungssystems

      (Subscript[a, 11])(Subscript[x, 1])+(Subscript[a, 12])(Subscript[x, 2])=(Subscript[b, 1])
(Subscript[a, 21])(Subscript[x, 1])+(Subscript[a, 22])(Subscript[x, 2])=(Subscript[b, 2])

Die Koeffizienten (Subscript[a, jk]) und die Konstanten (Subscript[b, j]) können mit Hilfe von Schiebereglern gewählt werden.

Manipulate[
ContourPlot[{a11 x1 + a12 x2==b1,a21 x1 + a22 x2==b2},{x1,-5,5},{x2,-5,5},ContourStyle->{Red,Blue},Axes->True,Frame->None],
{{a11,1,"(Subscript[a, 11])"},-3,3,Appearance->"Labeled"},
{{a12,1,"(Subscript[a, 12])"},-3,3,Appearance->"Labeled"},
{{a21,-1,"(Subscript[a, 21])"},-3,3,Appearance->"Labeled"},
{{a22,2,"(Subscript[a, 22])"},-3,3,Appearance->"Labeled"},
{{b1,1,"(Subscript[b, 1])"},-3,3,Appearance->"Labeled"},
{{b2,1,"(Subscript[b, 2])"},-3,3,Appearance->"Labeled"},ControlPlacement->Right]