Langfristige Änderungen der Bahn-
und Rotationsparameter der Erde

Didaktik der Astronomie, SS 2009

http://homepage.univie.ac.at/franz.embacher/Lehre/DidaktikAstronomie/ss2009/

Diese Visualisierung illustriert die langfristigen Änderungen der Bahn- und Rotationsparameter der Erde (übertrieben und nicht maßstabsgerecht dargestellt):
                                      
                         ({{Phänomen, Änderung der Größe, Periode (in 1000 Jahren)}, {Änderung der Exzentrizität, ϵ, (Subscript[T, ϵ])∼100, 413}, {Präzession des Eigendrehimpulses, β, (Subscript[T, β])∼25.7 -25.8}, {Änderung der Schiefe der Ekliptik, θ, (Subscript[T, θ])∼41}, {Rotation der Apsidenlinie, γ, (Subscript[T, γ])∼110}})

Nicht dargestellt ist eine periodische Kippung der Erdbahnebene im Raum mit einem Zyklus von etwa 100000 Jahren.

Zur Betrachtung schalten Sie den Schieberegler auf "Play" (Animation) und regeln Sie die Geschwindigkeit herunter! Die verschiedenen Effekte können einzeln sichtbar gemacht werden. Weiters können eingeblendet werden:
   - eine Einfärbung der Jahreszeiten (Nordsommer: rot, Nordwinter: blau)
   - die Apsidenlinie (Verbindung von Perihel und Aphel)
   - die Verbindungsline der beiden Äquinoktien (Tagundnachtgleichen)
Die Verschiebung der Äquinoktien relativ zum Perihel ist die Präzession der Äquinoktien (mit einem Zyklus von 21000 Jahren).

Clear[start];
Manipulate[
(* ------------------- Definitionen Beginn ---------------------- *)
a=149.6 (* große Halbachse (Mio km), zeitlich konstant *);
L=400 (* Betrag des Drehimpulsvektors, zeitlich konstant *);
T=200 (* von der Animation abgedeckter Zeitraum *);
{ϵMin,ϵHeute,ϵMax,Tϵ,κϵ}={0.1,0.2,0.5,100,-1} (* Exzentrizität, Periode, Vorzeichen der Änderung heute *);
φHeute=1 (* Position der Erde in der Grafik *);
{βHeute,Tβ,κβ}={-12.5*((2π)/360),25,1} (* Richtung der xy-Projektion des Drehimpulsvektors, Periode, Vorzeichen der Änderung heute *);
{θMin,θHeute,θMax,Tθ,κθ}={0.15,0.2,0.25,40,-1} (* Winkel des Drehimpulsvektors zur Normale auf die Bahnebene, Periode, Vorzeichen der Änderung heute *);
{γHeute,Tγ,κγ}={0,100,-1} (* Richtung der Apsidenlinie, Periode, Vorzeichen der Änderung heute *);
(* ------------------- Definitionen Ende ---------------------- *)

ϵ=If[ϵAn,κϵ(Sqrt[(1/4)(((ϵMax-ϵMin))^2)-(((ϵHeute-(1/2)(ϵMax+ϵMin)))^2)])Sin[((2π )/(Tϵ))t]+(ϵHeute-(1/2)(ϵMax+ϵMin))Cos[((2π )/(Tϵ))t]+(1/2)(ϵMax+ϵMin),ϵHeute];

β=((2π κβ)/(Tβ))If[βAn,1,0]t+βHeute;
θ=If[θAn,κθ(Sqrt[(1/4)(((θMax-θMin))^2)-(((θHeute-(1/2)(θMax+θMin)))^2)])Sin[((2π )/(Tθ))t]+(θHeute-(1/2)(θMax+θMin))Cos[((2π )/(Tθ))t]+(1/2)(θMax+θMin),θHeute];
γ=((2π κγ )/(Tγ))If[γAn,1,0]t+γHeute;
φE=φHeute;

pktSonne={0,0};
pktErde=(((1-(ϵ^2))a)/(1+ϵ Cos[φE])){Cos[φE+γ],Sin[φE+γ]};
drehimpulsProj=L Sin[θ]{Cos[β],Sin[β]};
φAequin=β-γ+(π/2);
kApsi=If[anApsi,1,0];
kAequ=If[anAequ,1,0];
Show[ParametricPlot[(((1-(ϵ^2))a)/(1+ϵ Cos[φ])){Cos[φ+γ],Sin[φ+γ]},{φ,φAequin,φAequin+π},PlotStyle->Red,Axes->None,PlotRange->{{-1.5a,1.5a},{-1.5a,1.5a}}],
ParametricPlot[(((1-(ϵ^2))a)/(1+ϵ Cos[φ])){Cos[φ+γ],Sin[φ+γ]},{φ,φAequin+π,φAequin+2π},PlotStyle->If[anJ,Blue,Red]],
Graphics[{
{RGBColor[0,0.75,0],Dotted,Line[{(((1-(ϵ^2))a kAequ)/(1+ϵ Cos[φAequin])){Cos[φAequin+γ],Sin[φAequin+γ]},(((1-(ϵ^2))a kAequ)/(1+ϵ Cos[φAequin+π])){Cos[φAequin+π+γ],Sin[φAequin+π+γ]}}]},
{Orange,Dotted,Line[{(((1-(ϵ^2))a kApsi)/(1+ϵ)){Cos[γ],Sin[γ]},-(((1-(ϵ^2))a kApsi)/(1-ϵ )){Cos[γ],Sin[γ]}}]},
{Green,Arrowheads[0.025],Arrow[{pktErde,pktErde+drehimpulsProj}]},
{PointSize[0.02],Orange,Point[pktSonne]},
{PointSize[0.016],Brown,Point[pktErde]}
}]
],
{{t,0 ,"t"},0,T,Appearance->"Labeled"},
{{ϵAn,False,"Var. d. Exzentrizität"},{True,False}},
{{βAn,False,"Präzession"},{True,False}},
{{θAn,False,"Schiefe der Ekliptik"},{True,False}},
{{γAn,False,"Rot. d. Apsidenlinie"},{True,False}},
{{anJ,False,Text[Style["Jahres",Red]Style["zeiten",Blue]]},{True,False}},
{{anApsi,False,Text[Style["Apsidenlinie",Orange]]},{True,False}},
{{anAequ,False,Text[Style["Äquinoktien",RGBColor[0,0.75,0]]]},{True,False}},
ControlPlacement->Right
]