3 Reihenentwicklung (Tayorreihen) und Approximation

Mathematische Grundlagen für das Lehramtsstudium Physik

Franz Embacher, Universität Wien, 2008
http://homepage.univie.ac.at/franz.embacher/grundlagen/

Näherungspolynome

Ein Polynom 3. Grades und seine Näherungspolynome

p0=3;
p1=3-4x;
p2=3-4x+7(x^2);
p3=3-4x+7(x^2)-6(x^3);
Plot[{p0,p1,p2,p3},{x,-1.4,1.4},PlotStyle->  {{Black,Dotted},{Black,Dashed},Black,Red},ImageSize->600]

Die Sinusfunktion und ihre ersten drei Näherungspolynome ungerader Ordnung

p1=x;
p3=x-((x^3)/(3!));
p5=x-((x^3)/(3!))+((x^5)/(5!));
f=Sin[x];
Plot[{p1,p3,p5,f},{x,-5,5},PlotStyle->  {{Black,Dotted},{Black,Dashed},Black,Red},PlotRange->{-4.1,4.1},ImageSize->600]

Die SInusfunktion und ihr Näherungspolynom 11. Ordnung

p11=Normal[Series[Sin[x],{x,0,11}]];
f=Sin[x];
Plot[{p11,f},{x,-8,8},PlotStyle ->{Black,Red},PlotRange->{-4.1,4.1},ImageSize->600]

Die SInusfunktion und ihre Näherungspolynome bis zur 20. Ordnung

Die maximale Ordnung k der angezeigten Näherungspolynome kann mit dem Schieberegler bis 20 erhöht werden.

Manipulate[
f=Sin[x];
taylorpolynome=Table[Normal[Series[f,{x,0,j}]],{j,0,k}];
gr1=Plot[f,{x,-10,10},PlotRange->{-10,10},PlotStyle->Red];
gr2=Plot[taylorpolynome,{x,-10,10},PlotRange->{-10,10}];
Show[gr1,gr2,ImageSize->600],
{k,1,20,1,Appearance->"Labeled"}]

Die Cosinusfunktion und ihre ersten drei Näherungspolynome gerader Ordnung

p0=1;
p2=1-((x^2)/(2!));
p4=1-((x^2)/(2!))+((x^4)/(4!));
f=Cos[x];
Plot[{p0,p2,p4,f},{x,-5,5},PlotStyle->  {{Black,Dotted},{Black,Dashed},Black,Red},PlotRange->{-4.1,4.1},ImageSize->600]

Taylorreihe und Näherungspolynom berechnen, plotten, Wert einsetzen

f=((x+3)/((x^2)+1)) (* gegebene Funktion *)
reihe=Series[f,{x,2,5}] (* Taylorreihe von f mit Mittelpunkt 2 bis zur 5. Ordnung *)
polynom=Normal[reihe] (* Näherungspolynom der Ordnung 5 *)
Plot[{polynom,f},{x,-2,5},PlotStyle->{Blue,Red},ImageSize->600] (* Plot *)
Show[%,Graphics[{Dotted,Line[{{2,0},{2,f/.x->2}}]}]] (* Plot mit Hilfslinie *)
polynom/.x->3 (* In das Näherungspolynom wird der Wert x = 3 eingesetzt. *)
%//N (* Die zuvor berechnete Zahl wird numerisch berechnet. *)

Konvergenzbereich

f=(1/(1-x));
p10=Normal[Series[f,{x,0,5}]];
Show[Plot[p10,{x,-1.5,1.1},PlotRange->{-3.2,20.5},PlotStyle->Black,ImageSize->600],Plot[f,{x,-1.5,1},PlotRange->{-3.2,20.5},PlotStyle->Red],Graphics[{Dotted,Line[{{1,0},{1,20.5}}]}]]